• Le premier chiffre n'est pas codé mais il détermine les tables à utiliser pour le codage des 6 chiffres suivants.
• La largeur d'une barre fine (0,33 mm en standard) est appelée le module.
• Il existe des barres de 1, 2, 3 ou 4modules; de même pour les espaces.
• Chaque chiffre est codé sur 7 modules comprenant chacun 2 barres et deux espaces.

• La marque de début de même que la marque de fin est : «101»
• La marque de séparation placée au milieu après le 7ème chiffre est : «01010»
• La longueur totale est toujours de 12 * 7 + 2 * 3 + 5 = 95 modules ; il y a toujours 30 barres au total.
• Les barres des séparateurs sont plus longues de 5 modules que les autres barres.
• Il faut des marges blanches de 11 modules à gauche et de 7 modules à droite au moins.

• La méthode graphique où chaque barre est «dessinée» comme un rectangle plein. Cette méthode permet de calculer la largeur de chaque barre au pixel près et de travailler sur des multiples de la largeur d'un pixel du périphérique utilisé. Cela donne une bonne précision surtout si le périphérique a une faible densité comme c'est le cas des écrans et des imprimantes à jet d'encre. Cette méthode demandes des routines de programmations spécifiques et ne permet pas de réaliser des codes barres avec un logiciel courant.
• La police spécifique dans laquelle chaque caractère est remplacé par le code barre d'un caractère. Cette méthode permet d'utiliser n'importe quel programme comme un traitement de texte ou un tableur (Par exemple LibreOffice, le clone gratuit de MSoffice !) Les mises à l'échelles en fonction du corps (La taille quoi) choisi peuvent entrainer de petites distorsions du dessin des barres. Avec une imprimante laser il n'y a aucun problème.

• Table A : Jeu de code A incluant le code barre et le chiffre en dessous.
• Table B : Jeu de code B incluant le code barre et le chiffre en dessous.
• Table C : Jeu de code C incluant le code barre et le chiffre en dessous.
• Table D : Jeu de chiffre et délimiteur de début
• Table E : Jeu de chiffre de début sans délimiteur (Nécessaire pour les logiciels de chez SAGE)

Copiez ce fichier dans le répertoire des polices, le plus souvent : \Windows\Fonts

• Chiffre N°1 de la table D (Incluant la marge gauche et le délimiteur de début)
• 6 chiffres des tables A ou B en fonction du premier chiffre
• Délimiteur central
• 6 chiffres de la table C
• Délimiteur de fin (Incluant la marge de droite)

Voici un petit programme écrit en Visual Basic 6 ; le
fichier d'installation copiera le programme,
les dépendances Visual Basic, les fichiers sources et la police.

Fichier d'auto-installation :

Fichier ZIP sans installation :

Public Function ean13$(chaine$)
  'Cette fonction est régie par la Licence Générale Publique Amoindrie GNU (GNU LGPL)
  'This function is governed by the GNU Lesser General Public License (GNU LGPL)
  'V 1.1.1
  'Paramètres : une chaine de 12 chiffres
  'Parameters : a 12 digits length string
  'Retour : * une chaine qui, affichée avec la police EAN13.TTF, donne le code barre
  ' * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with EAN13.TTF font
  ' * an empty string if the supplied parameter is no good
  Dim i%, checksum%, first%, CodeBarre$, tableA As Boolean
  ean13$ = ""
  'Vérifier qu'il y a 12 caractères
  'Check for 12 characters
  If Len(chaine$) = 12 Then
    'Et que ce sont bien des chiffres
    'And they are really digits
    For i% = 1 To 12
      If Asc(Mid$(chaine$, i%, 1)) < 48 Or Asc(Mid$(chaine$, i%, 1)) > 57 Then
i% = 0
Exit For
      End If
    Next
    If i% = 13 Then
      'Calcul de la clé de contrôle
      'Calculation of the checksum
      For i% = 12 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      checksum% = checksum% * 3
      For i% = 11 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      chaine$ = chaine$ & (10 - checksum% Mod 10) Mod 10
      'Le premier chiffre est pris tel quel, le deuxième vient de la table A
      'The first digit is taken just as it is, the second one come from table A
      CodeBarre$ = Left$(chaine$, 1) & Chr$(65 + Val(Mid$(chaine$, 2, 1)))
      first% = Val(Left$(chaine$, 1))
      For i% = 3 To 7
tableA = False
 Select Case i%
 Case 3
   Select Case first%
   Case 0 To 3
     tableA = True
   End Select
 Case 4
   Select Case first%
   Case 0, 4, 7, 8
     tableA = True
   End Select
 Case 5
   Select Case first%
   Case 0, 1, 4, 5, 9
     tableA = True
   End Select
 Case 6
   Select Case first%
   Case 0, 2, 5, 6, 7
     tableA = True
   End Select
 Case 7
   Select Case first%
   Case 0, 3, 6, 8, 9
     tableA = True
   End Select
 End Select
       If tableA Then
 CodeBarre$ = CodeBarre$ & Chr$(65 + Val(Mid$(chaine$, i%, 1)))
       Else
 CodeBarre$ = CodeBarre$ & Chr$(75 + Val(Mid$(chaine$, i%, 1)))
       End If
     Next
      CodeBarre$ = CodeBarre$ & "*"   'Ajout séparateur central / Add middle separator
      For i% = 8 To 13
CodeBarre$ = CodeBarre$ & Chr$(97 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "+"   'Ajout de la marque de fin / Add end mark
      ean13$ = CodeBarre$
    End If
  End If
End Function
			

Fichier Excel de démonstration

Fichier pour Libre Office

Language Auteur   Neobook 4 Jean-Louis HUVE Visual Foxpro Emile MAITREJEAN Delphi John SWIJSEN Delphi YARDIMLI EKIM Delphi Francisco FERNANDEZ C# Russell SAYERS Perl Simone FIORAVANTI Axapta Søe JESPER

Le code EAN 8

Public Function EAN8$(chaine$)
  'V 1.0.0
  'Paramètres : une chaine de 7 chiffres
  'Parameters : a 7 digits length string
  'Retour : * une chaine qui, affichée avec la police EAN13.TTF, donne le code barre
  ' * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with EAN13.TTF font
  ' * an empty string if the supplied parameter is no good
  Dim i%, checksum%, first%, CodeBarre$, tableA As Boolean
  EAN8$ = ""
  'Vérifier qu'il y a 7 caractères
  'Check for 7 characters
  If Len(chaine$) = 7 Then
    'Et que ce sont bien des chiffres
    'And they are really digits
    For i% = 1 To 7
      If Asc(Mid$(chaine$, i%, 1)) < 48 Or Asc(Mid$(chaine$, i%, 1)) > 57 Then
i% = 0
Exit For
      End If
    Next
    If i% = 8 Then
      'Calcul de la clé de contrôle
      'Calculation of the checksum
      For i% = 7 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      checksum% = checksum% * 3
      For i% = 6 To 1 Step -2
checksum% = checksum% + Val(Mid$(chaine$, i%, 1))
      Next
      chaine$ = chaine$ & (10 - checksum% Mod 10) Mod 10
      'Les 4 premier chiffre viennent de la table A
      'The first 4 digits come from table A
      CodeBarre$ = ""   'Ajout marque de début / Add start mark
      For i% = 1 To 4
 CodeBarre$ = CodeBarre$ & Chr$(65 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "*"   'Ajout séparateur central / Add middle separator
      For i% = 5 To 8
CodeBarre$ = CodeBarre$ & Chr$(97 + Val(Mid$(chaine$, i%, 1)))
      Next
      CodeBarre$ = CodeBarre$ & "+"   'Ajout de la marque de fin / Add end mark
      EAN8$ = CodeBarre$
    End If
  End If
End Function